115 lines
3.1 KiB
Fortran
115 lines
3.1 KiB
Fortran
SUBROUTINE DLASET( UPLO, M, N, ALPHA, BETA, A, LDA )
|
|
*
|
|
* -- LAPACK auxiliary routine (version 2.0) --
|
|
* Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
|
|
* Courant Institute, Argonne National Lab, and Rice University
|
|
* October 31, 1992
|
|
*
|
|
* .. Scalar Arguments ..
|
|
CHARACTER UPLO
|
|
INTEGER LDA, M, N
|
|
DOUBLE PRECISION ALPHA, BETA
|
|
* ..
|
|
* .. Array Arguments ..
|
|
DOUBLE PRECISION A( LDA, * )
|
|
* ..
|
|
*
|
|
* Purpose
|
|
* =======
|
|
*
|
|
* DLASET initializes an m-by-n matrix A to BETA on the diagonal and
|
|
* ALPHA on the offdiagonals.
|
|
*
|
|
* Arguments
|
|
* =========
|
|
*
|
|
* UPLO (input) CHARACTER*1
|
|
* Specifies the part of the matrix A to be set.
|
|
* = 'U': Upper triangular part is set; the strictly lower
|
|
* triangular part of A is not changed.
|
|
* = 'L': Lower triangular part is set; the strictly upper
|
|
* triangular part of A is not changed.
|
|
* Otherwise: All of the matrix A is set.
|
|
*
|
|
* M (input) INTEGER
|
|
* The number of rows of the matrix A. M >= 0.
|
|
*
|
|
* N (input) INTEGER
|
|
* The number of columns of the matrix A. N >= 0.
|
|
*
|
|
* ALPHA (input) DOUBLE PRECISION
|
|
* The constant to which the offdiagonal elements are to be set.
|
|
*
|
|
* BETA (input) DOUBLE PRECISION
|
|
* The constant to which the diagonal elements are to be set.
|
|
*
|
|
* A (input/output) DOUBLE PRECISION array, dimension (LDA,N)
|
|
* On exit, the leading m-by-n submatrix of A is set as follows:
|
|
*
|
|
* if UPLO = 'U', A(i,j) = ALPHA, 1<=i<=j-1, 1<=j<=n,
|
|
* if UPLO = 'L', A(i,j) = ALPHA, j+1<=i<=m, 1<=j<=n,
|
|
* otherwise, A(i,j) = ALPHA, 1<=i<=m, 1<=j<=n, i.ne.j,
|
|
*
|
|
* and, for all UPLO, A(i,i) = BETA, 1<=i<=min(m,n).
|
|
*
|
|
* LDA (input) INTEGER
|
|
* The leading dimension of the array A. LDA >= max(1,M).
|
|
*
|
|
* =====================================================================
|
|
*
|
|
* .. Local Scalars ..
|
|
INTEGER I, J
|
|
* ..
|
|
* .. External Functions ..
|
|
LOGICAL LSAME
|
|
EXTERNAL LSAME
|
|
* ..
|
|
* .. Intrinsic Functions ..
|
|
INTRINSIC MIN
|
|
* ..
|
|
* .. Executable Statements ..
|
|
*
|
|
IF( LSAME( UPLO, 'U' ) ) THEN
|
|
*
|
|
* Set the strictly upper triangular or trapezoidal part of the
|
|
* array to ALPHA.
|
|
*
|
|
DO 20 J = 2, N
|
|
DO 10 I = 1, MIN( J-1, M )
|
|
A( I, J ) = ALPHA
|
|
10 CONTINUE
|
|
20 CONTINUE
|
|
*
|
|
ELSE IF( LSAME( UPLO, 'L' ) ) THEN
|
|
*
|
|
* Set the strictly lower triangular or trapezoidal part of the
|
|
* array to ALPHA.
|
|
*
|
|
DO 40 J = 1, MIN( M, N )
|
|
DO 30 I = J + 1, M
|
|
A( I, J ) = ALPHA
|
|
30 CONTINUE
|
|
40 CONTINUE
|
|
*
|
|
ELSE
|
|
*
|
|
* Set the leading m-by-n submatrix to ALPHA.
|
|
*
|
|
DO 60 J = 1, N
|
|
DO 50 I = 1, M
|
|
A( I, J ) = ALPHA
|
|
50 CONTINUE
|
|
60 CONTINUE
|
|
END IF
|
|
*
|
|
* Set the first min(M,N) diagonal elements to BETA.
|
|
*
|
|
DO 70 I = 1, MIN( M, N )
|
|
A( I, I ) = BETA
|
|
70 CONTINUE
|
|
*
|
|
RETURN
|
|
*
|
|
* End of DLASET
|
|
*
|
|
END
|