122 lines
3.3 KiB
Fortran
122 lines
3.3 KiB
Fortran
SUBROUTINE DGELQ2( M, N, A, LDA, TAU, WORK, INFO )
|
|
*
|
|
* -- LAPACK routine (version 2.0) --
|
|
* Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
|
|
* Courant Institute, Argonne National Lab, and Rice University
|
|
* February 29, 1992
|
|
*
|
|
* .. Scalar Arguments ..
|
|
INTEGER INFO, LDA, M, N
|
|
* ..
|
|
* .. Array Arguments ..
|
|
DOUBLE PRECISION A( LDA, * ), TAU( * ), WORK( * )
|
|
* ..
|
|
*
|
|
* Purpose
|
|
* =======
|
|
*
|
|
* DGELQ2 computes an LQ factorization of a real m by n matrix A:
|
|
* A = L * Q.
|
|
*
|
|
* Arguments
|
|
* =========
|
|
*
|
|
* M (input) INTEGER
|
|
* The number of rows of the matrix A. M >= 0.
|
|
*
|
|
* N (input) INTEGER
|
|
* The number of columns of the matrix A. N >= 0.
|
|
*
|
|
* A (input/output) DOUBLE PRECISION array, dimension (LDA,N)
|
|
* On entry, the m by n matrix A.
|
|
* On exit, the elements on and below the diagonal of the array
|
|
* contain the m by min(m,n) lower trapezoidal matrix L (L is
|
|
* lower triangular if m <= n); the elements above the diagonal,
|
|
* with the array TAU, represent the orthogonal matrix Q as a
|
|
* product of elementary reflectors (see Further Details).
|
|
*
|
|
* LDA (input) INTEGER
|
|
* The leading dimension of the array A. LDA >= max(1,M).
|
|
*
|
|
* TAU (output) DOUBLE PRECISION array, dimension (min(M,N))
|
|
* The scalar factors of the elementary reflectors (see Further
|
|
* Details).
|
|
*
|
|
* WORK (workspace) DOUBLE PRECISION array, dimension (M)
|
|
*
|
|
* INFO (output) INTEGER
|
|
* = 0: successful exit
|
|
* < 0: if INFO = -i, the i-th argument had an illegal value
|
|
*
|
|
* Further Details
|
|
* ===============
|
|
*
|
|
* The matrix Q is represented as a product of elementary reflectors
|
|
*
|
|
* Q = H(k) . . . H(2) H(1), where k = min(m,n).
|
|
*
|
|
* Each H(i) has the form
|
|
*
|
|
* H(i) = I - tau * v * v'
|
|
*
|
|
* where tau is a real scalar, and v is a real vector with
|
|
* v(1:i-1) = 0 and v(i) = 1; v(i+1:n) is stored on exit in A(i,i+1:n),
|
|
* and tau in TAU(i).
|
|
*
|
|
* =====================================================================
|
|
*
|
|
* .. Parameters ..
|
|
DOUBLE PRECISION ONE
|
|
PARAMETER ( ONE = 1.0D+0 )
|
|
* ..
|
|
* .. Local Scalars ..
|
|
INTEGER I, K
|
|
DOUBLE PRECISION AII
|
|
* ..
|
|
* .. External Subroutines ..
|
|
EXTERNAL DLARF, DLARFG, XERBLA
|
|
* ..
|
|
* .. Intrinsic Functions ..
|
|
INTRINSIC MAX, MIN
|
|
* ..
|
|
* .. Executable Statements ..
|
|
*
|
|
* Test the input arguments
|
|
*
|
|
INFO = 0
|
|
IF( M.LT.0 ) THEN
|
|
INFO = -1
|
|
ELSE IF( N.LT.0 ) THEN
|
|
INFO = -2
|
|
ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
|
|
INFO = -4
|
|
END IF
|
|
IF( INFO.NE.0 ) THEN
|
|
CALL XERBLA( 'DGELQ2', -INFO )
|
|
RETURN
|
|
END IF
|
|
*
|
|
K = MIN( M, N )
|
|
*
|
|
DO 10 I = 1, K
|
|
*
|
|
* Generate elementary reflector H(i) to annihilate A(i,i+1:n)
|
|
*
|
|
CALL DLARFG( N-I+1, A( I, I ), A( I, MIN( I+1, N ) ), LDA,
|
|
$ TAU( I ) )
|
|
IF( I.LT.M ) THEN
|
|
*
|
|
* Apply H(i) to A(i+1:m,i:n) from the right
|
|
*
|
|
AII = A( I, I )
|
|
A( I, I ) = ONE
|
|
CALL DLARF( 'Right', M-I, N-I+1, A( I, I ), LDA, TAU( I ),
|
|
$ A( I+1, I ), LDA, WORK )
|
|
A( I, I ) = AII
|
|
END IF
|
|
10 CONTINUE
|
|
RETURN
|
|
*
|
|
* End of DGELQ2
|
|
*
|
|
END
|